全面掌握Solidity智能合约开发

2024年09月25日更新 796 人订阅
原价: ¥ 46 限时优惠
专栏简介 跟我学 Solidity :开发环境 跟我学 Solidity:关于变量 跟我学 Solidity : 变量的存储 跟我学 Solidity :引用变量 跟我学 Solidity :函数 跟我学 Solidity :合约的创建和继承 跟我学 Solidity :工厂模式 用Web3.js构建第一个Dapp 跟我学Solidity:事件 Solidity 中 immutable (不可变量)与constant(常量) [译] Solidity 0.6.x更新:继承 解析 Solidity 0.6 新引入的 try/catch 特性 探究新的 Solidity 0.8 版本 探索以太坊合约委托调用(DelegateCall) 停止使用Solidity的transfer() 使用工厂提高智能合约安全性 Solidity 怎样写出最节省Gas的智能合约[译] Solidity 优化 - 编写 O(1) 复杂度的可迭代映射 Solidity 优化 - 控制 gas 成本 Solidity 优化 - 减少智能合约的 gas 消耗的8种方法 Solidity 优化 - 如何维护排序列表 Solidity 优化:打包变量优化 gas 使用 Solidity 瞬态存储操作码 在 Solidity中使用值数组以降低 gas 消耗 Gas 优化:Solidity 中的使用动态值数组 计算Solidity 函数的Gas 消耗 Solidity 技巧:如何减少字节码大小及节省 gas 一些简单的 Gas 优化基础 "Stack Too Deep(堆栈太深)" 解决方案 智能合约Gas 优化的几个技术 合约实践:避免区块Gas限制导致问题 如何缩减合约以规避合约大小限制 Solidity 类特性 无需gas代币和ERC20-Permit还任重而道远 智能合约实现白名单的3个机制 Solidity智能合约安全:防止重入攻击的4种方法 Solidity 十大常见安全问题 [译]更好Solidity合约调试工具: console.log 智能合约开发的最佳实践 - 强烈推荐 全面理解智能合约升级 Solidity可升级代理模式: 透明代理与UUPS代理 使用OpenZeppelin编写可升级的智能合约 实战:调整NFT智能合约,减少70%的铸币Gas成本 Solidity 优化 - 隐藏的 Gas 成本 Gas 技巧:Solidity 中利用位图大幅节省Gas费 Solidity Gas 优化 - 理解不同变量 Gas 差异 关于Solidity 事件,我希望早一点了解到这些 Solidity 编码规范推荐标准 深入了解 Solidity bytes OpenZeppelin Contracts 5.0 版本发布 Solidity Gas优化:高效的智能合约策略 智能合约安全的新最低测试标准:Fuzz / Invariant Test 智能合约的白名单技术 模糊测试利器 - Echidna 简介 智能合约设计模式:代理 离线授权 NFT EIP-4494:ERC721 -Permit

解析 Solidity 0.6 新引入的 try/catch 特性

  • Tiny熊
  • 发布于 2020-04-13 18:24
  • 阅读 10465

Solidity 0.6 终于可以捕获错误啦

在以太坊中对智能合约进行编程与常规开发人员所用的编程有很大不同,并且缺乏基本处理错误工具一直是一个问题,经常导致智能合约逻辑“破裂”。

当EVM中的交易执行触发revert时,所有状态更改都将回滚并中止执行。 因此,来自现代编程语言的开发人员在编写Solidity时,都可能最终会搜索“如何在Solidity中try/catch”来处理这些回滚。

Solidity 0.6的新功能里最酷的功能之一是使用try/catch语句。

try/catch 的文档可以点击这里查看

为什么需要 try / catch

try/catch 结构可以用于许多场景:

  • 如果一个调用回滚(revert)了,我们不想终止交易的执行。

  • 我们想在同一个交易中重试调用、存储错误状态、对失败的调用做出处理等等。

在 Solidity 0.6 之前,模拟 try/catch 仅有的方式是使用低级的调用如: call, delegatecallstaticcall.

这是一个简单的示例,说明如何内部调用同一合约的另一个函数中实现某种try/catch

pragma solidity <0.6.0;

contract OldTryCatch {

    function execute(uint256 amount) external {

        // 如果执行失败,低级的call会返回 `false` 
        (bool success, bytes memory returnData) = address(this).call(
            abi.encodeWithSignature(
                "onlyEven(uint256)",
                amount
            )
        );

        if (success) {
            // handle success            
        } else {
            // handle exception
        }
    }

    function onlyEven(uint256 a) public {
        // Code that can revert
        require(a % 2 == 0, "Ups! Reverting");
        // ...
    }
}

当调用 execute(uint256 amount), 输入的参数 amount 会通过低级的call调用传给 onlyEven(uint256) 函数, call 调用会返回 bool 值作为第一个参数来指示调用的成功与否,而不会让整个交易失败。

参考文档: Solidity中文 文档-地址类型的成员

请注意,在对 onlyEven(uint256) 的低级call调用返回了false的情况下,它会(必需)还原在低级调用执行中所做的状态更改,但是在调用之前和/或之后的更改不会被还原应用。

这种 try/catch的定制实现虽然有点脆弱,但它既可以用于从同一合约(如刚刚的例子)中调用函数,也可以(更多的)用于外部合约的调用。

这是控制外部调用的错误的一种有用方法,但我们应始终记住,由于执行我们不能信任的外部代码可能会出现安全性问题,因此不建议使用低级调用

这是为什么 try/catch 特性用于外部调用引入 ,在最新的编译器中,可以这样写:

pragma solidity <0.7.0;

contract CalledContract {    
    function someFunction() external {
        // Code that reverts
        revert();
    }
}

contract TryCatcher {

    event CatchEvent();
    event SuccessEvent();

    CalledContract public externalContract;

    constructor() public {
        externalContract = new CalledContract();
    }

    function execute() external {

        try externalContract.someFunction() {
            // Do something if the call succeeds
            emit SuccessEvent();
        } catch {
            // Do something in any other case
            emit CatchEvent();
        }
    }
}

try/catch 概述

就像前面提到的,新功能 try/catch 仅适用于外部调用

参考文档: Solidity中文 文档-外部调用

如果我们想在合同中的内部调用中使用try/catch模式(如第一个示例),我们仍然可以使用前面介绍的低级调用的方法,或者可以使用全局变量this来调用内部函数,就像外部调用一样。

如上面的例子:

try this.onlyEven(3) {
    ...
} catch {
    ...
}

如果尝试使用新语法进行低级调用,则编译器将提示错误:

错误提示

每当我们尝试使用try/catch语法进行低级调用时,编译器都会返回TypeError错误提示。

如果仔细阅读了编译器错误信息,则TypeError提示会指出,try/catch甚至可以用于创建合约,让我们来尝试一下:

pragma solidity <0.7.0;

contract CalledContract {

    constructor() public {
        // Code that reverts
        revert();
    }

    // ...
}

contract TryCatcher {

    // ...

    function execute() public {

        try new CalledContract() {
            emit SuccessEvent();
        } catch {
            emit CatchEvent();
        }
    }
}

要注意,在try代码块内的任何内容仍然可以停止执行, try仅针对于call。 例如,在try 成功后,依旧可以 revert 交易,例如下面的例子:

function execute() public {

    try externalContract.someFunction() {
        // 尽管外部调用成功了, 依旧可以回退交易。
        revert();
    } catch {
       ...
    }

因此,请注意:try 代码块内的 revert 不会被catch本身捕获

返回值和作用域内变量

Try / catch 允许使用从外部调用返回值和作用域内变量。

构造调用的例子:

contract TryCatcher {

    // ...

    function execute() public {

        try new CalledContract() returns(CalledContract returnedInstance) {
            // returnedInstance  是新部署合约的地址
            emit SuccessEvent();
        } catch {
            emit CatchEvent();
        }
    }
}

外部调用:

contract CalledContract {    
    function getTwo() public returns (uint256) {
        return 2;
    }
}

contract TryCatcher {

    CalledContract public externalContract;

    // ...

    function execute() public returns (uint256, bool) {

        try externalContract.getTwo() returns (uint256 v) {
            uint256 newValue = v + 2;
            return (newValue, true);
        } catch {
            emit CatchEvent();
        }

        // ...
    }
}

注意本地变量newValue 和返回值只在 try 代码块内有效。这同样适用于在catch块内声明的任何变量。

要在catch语句中使用返回值,我们可以使用以下语法:

contract TryCatcher {

    event ReturnDataEvent(bytes someData);

    // ...

    function execute() public returns (uint256, bool) {

        try externalContract.someFunction() {
            // ...
        } catch (bytes memory returnData) {            
            emit ReturnDataEvent(returnData);
        }
    }
}

外部调用返回的数据将转换为bytes ,并可以在catch 块内进行访问。 注意,该catch 中考虑了各种可能的 revert 原因,并且如果由于某种原因解码返回数据失败,则将在调用合约的上下文中产生该失败-因此执行try/catch的交易也会失败。

指定 catch 条件子句

Solidity 的 try/catch也可以包括特定的catch条件子句。 已经可以使用的第一个特定的catch条件子句是:

contract TryCatcher {

    event ReturnDataEvent(bytes someData);
    event CatchStringEvent(string someString);
    event SuccessEvent();

    // ...

    function execute() public {

        try externalContract.someFunction() {
            emit SuccessEvent();
        } catch Error(string memory revertReason) {
            emit CatchStringEvent(revertReason);
        } catch (bytes memory returnData) {
            emit ReturnDataEvent(returnData);
        }
    }
}

在这里,如果还原是由require(condition,"reason string")revert("reason string")引起的,则错误签名与catch Error(string memory revertReason)子句匹配,然后与之匹配块被执行。 在任何其他情况下,(例如, assert失败)都会执行更通用的 catch (bytes memory returnData) 子句。

注意,catch Error(string memory revertReason)不能捕获除上述两种情况以外的任何错误。 如果我们仅使用它(不使用其他子句),最终将丢失一些错误。 通常,必须将catchcatch(bytes memory returnData)catch Error(string memory revertReason)一起使用,以确保我们涵盖了所有可能的revert原因。

在一些特定的情况下,如果catch Error(string memory revertReason) 解码返回的字符串失败,catch(bytes memory returnData)(如果存在)将能够捕获它。

计划在将来的Solidity版本中使用更多条件的catch子句。

Gas 失败

如果交易没有足够的gas执行,则out of gas error 是不能捕获到的。

在某些情况下,我们可能需要为外部调用指定gas,因此,即使交易中有足够的gas,如果外部调用的执行需要的gas比我们设置的多,内部out of gas 错误可能会被低级的catch子句捕获。

pragma solidity <0.7.0;

contract CalledContract {

    function someFunction() public returns (uint256) {
        require(true, "This time not reverting");
    }
}

contract TryCatcher {

    event ReturnDataEvent(bytes someData);
    event SuccessEvent();

    CalledContract public externalContract;

    constructor() public {
        externalContract = new CalledContract();
    }

    function execute() public {
 // Setting gas to 20
        try externalContract.someFunction.gas(20)() {
            // ...
        } catch Error(string memory revertReason) {
            // ...
        } catch (bytes memory returnData) {
            emit ReturnDataEvent(returnData);
        }
    }
}

当gas设置为20时,try调用的执行将用掉所有的 gas,最后一个catch语句将捕获异常:catch (bytes memory returnData)。 相反,将gas设置为更大的量(例如:2000)将执行try块会成功。

结论

总结一下,这里是使用Solidity新添加的try/catch时要记住的事项:

  • 这是仅仅提供给外部调用的特性,如上所述。部署新合约也被视为外部调用。
  • 该功能能够捕获仅在调用内部产生的异常。调用后的 try 代码块是在成功之后执行。不会捕获try 代码块中的任何异常。
  • 如果函数调用返回一些变量,则可以在以下执行块中使用它们(如以上示例中所述)。
    • 如果执行了 try 成功代码块,则必须声明与函数调用实际返回值相同类型的变量。
    • 如果执行了低级的catch块,则返回值是类型为bytes的变量。任何特定条件的catch子句都有其自己的返回值类型。
  • 请记住,低级catch (bytes memory returnData) 子句能够捕获所有异常,而特定条件的catch子句只捕获对应的错误。处理各种异常时,请考虑同时使用两者。
  • 在为 try 外部调用设置特定的gas使用量时,低级的catch子句会捕获最终的out of gas错误。 但如果交易本身没有足够的 gas执行代码,则out of gas是没法捕获的。

本文翻译自 openzeppelin 论坛,原文

点赞 3
收藏 6
分享
本文参与登链社区写作激励计划 ,好文好收益,欢迎正在阅读的你也加入。

0 条评论

请先 登录 后评论